Por conta de repetidos erros ao exibir a cotação do dólar em relação ao real brasileiro, a Google removeu a ferramenta do ar no dia 26/12/2024 para todos os residentes do Brasil. Muitos usuários do Google Sheets utilizam a função GOOGLEFINANCE para obter a cotação do dólar em suas planilhas de trabalho ou até mesmo pessoais.
Vamos te mostrar algumas alternativas ao =GOOGLEFINANCE("CURRENCY:USDBRL") e que são confiáveis.
Por que o GOOGLEFINANCE(“CURRENCY:USDBRL”) não está retornando dados?
Devido a cotação inconsistente mostrada no buscador da Google durante e após o Natal de 2024, a Justiça solicitou explicações ao Banco Central e a própria Google optou por remover da ferramenta de conversão de dólar para real do ar.
Isso ocorreu devido ao feriado no Brasil, já que o mercado estava fechado para negociações, então a cotação com dados fornecidos pela Morningstar (fornecedora dos dados usados pela Google) foi baseado em uma amostra de dados pouco relevante.
Alternativas ao GOOGLEFINANCE(“CURRENCY:USDBRL”)
Existem algumas alternativas confiáveis para obter a cotação de outras moedas, como o dólar, no Google Sheets.
Utilizando APIs de terceiros
Você pode buscar uma de sua preferência, mas é essencial confiar numa fonte de extrema qualidade: o próprio Banco Central.
Existe um endpoint que busca o PTAX (taxa de câmbio) de compra e venda do dólar diretamente em uma API oficial do Banco Central.
https://olinda.bcb.gov.br/olinda/servico/PTAX/versao/v1/odata/CotacaoDolarDia(dataCotacao=@dataCotacao)?@dataCotacao='01-08-2025'&$format=text/htmlA partir desse link, que retorna uma resposta no formato HTML, você pode utilizar a função IMPORTHTML no Google Sheets e importar a tabela com cotação de compra e venda do dólar.
Se você acessar essa URL, verá algo como isso:
Para importar essa tabela por inteiro no Google Sheets, use:
Cotação do dólar com IMPORTXML + API Banco Central (fechamento)
=IMPORTHTML("https://olinda.bcb.gov.br/olinda/servico/PTAX/versao/v1/odata/CotacaoDolarDia(dataCotacao=@dataCotacao)?@dataCotacao='" & TEXTO(SE(DIA.DA.SEMANA(HOJE(); 2)=1; HOJE()-3; SE(DIA.DA.SEMANA(HOJE(); 2)=7; HOJE()-2; HOJE()-1)); "MM-DD-YYYY") & "'&$format=text/html"; "table"; 1)EDITADO EM 15/01/2025: Nesse endpoint da API, o Banco Central entrega a cotação de fechamento com 1 dia de atraso e somente para dias úteis, o que pode ocasionar erros se o parâmetro dataCotacao não for definido corretamente.
Com isso, no lugar de simplesmente usar somente a função HOJE() no parâmetro dataCotacao, nós fizemos uma condicional usando =SE() que irá retornar sempre o dia útil anterior – embora não considere feriados.
O retorno será algo do tipo:
Agora, se no lugar da tabela com todas as informações, você quiser retornar somente a cotação de fato, basta combinar IMPORTHTML com a função ÍNDICE:
=ÍNDICE(IMPORTHTML("https://olinda.bcb.gov.br/olinda/servico/PTAX/versao/v1/odata/CotacaoDolarDia(dataCotacao=@dataCotacao)?@dataCotacao='" & TEXTO(SE(DIA.DA.SEMANA(HOJE(); 2)=1; HOJE()-3; SE(DIA.DA.SEMANA(HOJE(); 2)=7; HOJE()-2; HOJE()-1)); "MM-DD-YYYY") & "'&$format=text/html"; "table"; 1); 2; 1)Isso fará que seja retornado somente a cotação de compra, por exemplo: R$ 6,1315
Para retornar somente a cotação de venda, altere o último 1 para 2.
Cotação do dólar com IMPORTXML + API Banco Central (diário)
Se você precisa de cotação do dia e quer continuar consumindo dados diretamente do Banco Central, sem depender de esperar a cotação de fechamento com 1 dia de atraso, existe um outro endpoint que traz o preço de abertura, 3 cotações atualizadas entre 11h e 13h, e a cotação de fechamento.
Use a função abaixo para importar a tabela por completo na sua planilha:
=IMPORTHTML("https://olinda.bcb.gov.br/olinda/servico/PTAX/versao/v1/odata/CotacaoMoedaDia(moeda=@moeda,dataCotacao=@dataCotacao)?@moeda='USD'&@dataCotacao='01-15-2025'&$format=text/html"; "table"; 1)
Note que eu capturei essa imagem no dia 15/01/2025 às 12h57, antes da terceira intermediária e também da última cotação do dia – embora já não tenha que consumir um dado com 1 dia de atraso.
Além da API do Banco Central, outra opção válida pra quem só quer uma cotação de compra ou venda mais recente e atualizada, e que não tem necessidade de controle de datas, é a AwesomeAPI: https://economia.awesomeapi.com.br/xml/last/USD-BRL
Cotação do dólar com IMPORTXML + AwesomeAPI
Nesse caso, você deve usar a função IMPORTXML: =IMPORTXML("https://economia.awesomeapi.com.br/xml/last/USD-BRL";"//bid")
O parâmetro XPATH da função quando //bid irá retornar o preço de compra do dólar, mas também pode ser:
- //ask para retornar o preço de venda
- //high para retornar o maior preço registrado no dia
- //low para retornar o menor preço registrado no dia
BÔNUS: Função personalizada com Apps Script
Além de poder acessar as cotações usando funções nativas do Google Planilhas, é possível também criar uma função personalizada no Apps Script para obter a cotação do dólar.
Vá em Extensões > Apps Script e use o código:
function obterCotacaoDolar() {
var url = 'https://economia.awesomeapi.com.br/json/last/USD-BRL';
var response = UrlFetchApp.fetch(url);
var dados = JSON.parse(response.getContentText());
return dados["USDBRL"].bid; // Retorna o valor atual do dólar
}Salve o projeto, execute para dar as permissões necessárias e use =obterCotacaoDolar() na sua planilha.
Conclusão
Bom, existem diversas alternativas ao uso do GOOGLEFINANCE(“CURRENCY:USDBRL”) para buscar a cotação do dólar em relação ao real brasileiro. Esperamos que essas dicas te ajudem a contornar essa questão enquanto a Google não retorna a normalidade com as cotações no Brasil.
Teste os métodos sugeridos acima e escolha o mais adequado para a sua planilha.
Quer aprender mais?
Confira outros assuntos e passo a passo sobre Google Sheets e Apps Script no nosso blog. Participe também da Comunidados, que é o nosso grupo 100% gratuito no WhatsApp.
